Drosophila predicted eye regulatory network database

The predicted Drosophila eye regulatory network database regroup the results of RNA-seq experiments across 72 wild type, genetic perturbations and sorted cell types of third instar larvae eye-antennal disc. From these experiments we inferred a co-expression network and a predicted direct TF targetome for hundreds of TFs. These network are stocked in a database that can be downloaded or requested as explained below.

Architecture of the Drosophila predicted eye regulatory network database

Requests via the query form

Go to the Query page, select the fields you are interested in and submit.

N.B. If your query is not possible via the Query page, it is possible to download the full database or to build your own Cypher queries via the Cypher query page or the CyNeo4j plugin in Cytoscape.

Custom requests via the Cypher form

For a short overview of the Cypher language take a look at the Cypher language documentation.

Go to the Cypher query page, to enter your custom Cypher query and submit.

TF to co-expressed genes

e.g. Ask for genes co-expressed with glass (all methods and thresholds)

MATCH (tf:`TFs` { gene_symbol: "gl" })-[coexpressed_relation:`TF_coexpressed_with_genes`]->(coexpressedgene:`CoExpressedGenes`)
  RETURN
         tf.gene_symbol, tf.fbgn, coexpressedgene.gene_symbol,
         coexpressedgene.fbgn, type(coexpressed_relation), coexpressed_relation.coexpression_method_type,
         coexpressed_relation.coexpression_method_threshold

Responsive image

TF to target genes

Simple

e.g. Ask for glass high confidence predicted target genes (only returns genes names, no other information)

MATCH (gene:`high_confidence_predicted_target_genes_for_gl`)
  RETURN
         genes.gene_symbol, genes.fbgn

Responsive image

Full

e.g. Ask for glass high confidence predicted target genes predicted from GENIE3 0.008 co-expressed gene set with all details of the prediction (motifs, regions, genes...)

MATCH (tf:`TFs` { gene_symbol: "gl" })-[tf2motif_relation:`GENIE3_0.008_high_confidence_predicted_target_for_TF`]
->(motif:`Motifs`)-[motif2region_relation:`GENIE3_0.008_high_confidence_predicted_target_for_TF`]
->(target_region:`Regions`)-[region2gene_relation:`GENIE3_0.008_high_confidence_predicted_target_for_TF`]
->(target_gene:`HighConfidencePredictedTargetGenes`)
  WHERE tf2motif_relation.name = motif2region_relation.name
        AND tf2motif_relation.name = region2gene_relation.name
  RETURN
         tf.gene_symbol, tf.fbgn, target_gene.gene_symbol,
         target_gene.fbgn, region2gene_relation.gene_rank, motif.motif_name,
         tf2motif_relation.motif_rank, tf2motif_relation.NES_score, target_region.region_id,
         target_region.chromosome, target_region.start_position, target_region.end_position,
         motif2region_relation.region_rank, type(tf2motif_relation), tf2motif_relation.confidence_level,
         tf2motif_relation.coexpression_method_type, tf2motif_relation.coexpression_method_threshold

Responsive image

Target gene to TFs

Simple

e.g. Ask for TF regulation glass in the high confidence predicted network (return only gene names, no other information)

MATCH (tf:`TFs_for_high_confidence_predicted_target_gene_gl`)
  RETURN
         tf.gene_symbol, tf.fbgn

Responsive image

N.B. Similar requests can also be used for motifs an regions:

TFs_for_medium_confidence_predicted_motif_"motif_name"
TFs_for_high_confidence_predicted_motif_"motif_name
TFs_for_medium_confidence_predicted_target_region_"region_id"
TFs_for_high_confidence_predicted_target_region_"region_id"

Full

e.g. Ask for TFs predicted to regulate glass in the high confidence network starting from the PTM 10e-8 dataset. All information about motifs and regulatory regions is available via this query.

MATCH (tf:`TFs`)-[tf2motif_relation:`PTM_greater_10e-8_high_confidence_predicted_target_for_TF`]
->(motif:`Motifs`)-[motif2region_relation:`PTM_greater_10e-8_high_confidence_predicted_target_for_TF`]
->(target_region:`Regions`)-[region2gene_relation:`PTM_greater_10e-8_high_confidence_predicted_target_for_TF`]
->(target_gene:`HighConfidencePredictedTargetGenes` { gene_symbol: "gl" })
  WHERE tf2motif_relation.name = motif2region_relation.name
        AND tf2motif_relation.name = region2gene_relation.name
  RETURN
         tf.gene_symbol, tf.fbgn, target_gene.gene_symbol,
         target_gene.fbgn, region2gene_relation.gene_rank, motif.motif_name,
         tf2motif_relation.motif_rank, tf2motif_relation.NES_score, target_region.region_id,
         target_region.chromosome, target_region.start_position, target_region.end_position,
         motif2region_relation.region_rank, type(tf2motif_relation), tf2motif_relation.confidence_level,
         tf2motif_relation.coexpression_method_type, tf2motif_relation.coexpression_method_threshold

Responsive image

TF to motifs

e.g. Ask for binding motifs related to glass in our collection.

MATCH (tf:`TFs` { gene_symbol: "gl" })-[tf_to_motif:`is_possible_TF_for_motif`]->(motif:`Motifs`)
  RETURN
         motif.motif_name

Responsive image

Genomic coordinates to predicted regulators and related genes

e.g. Ask for TFs predicted to binding in a specific genomic region using dm3 coordinates.

MATCH (target_region:`Regions`)
  WHERE target_region.chromosome = "chr3R"
        AND 14200832 <= target_region.end_position
        AND 14201013 >= target_region.start_position
MATCH (tf:`TFs`)-[tf2motif_relation:`PTM_greater_10e-8_high_confidence_predicted_target_for_TF`]
->(motif:`Motifs`)-[motif2region_relation:`PTM_greater_10e-8_high_confidence_predicted_target_for_TF`]
->(target_region)-[region2gene_relation:`PTM_greater_10e-8_high_confidence_predicted_target_for_TF`]
->(target_gene:`HighConfidencePredictedTargetGenes`)
  WHERE tf2motif_relation.name = motif2region_relation.name
        AND tf2motif_relation.name = region2gene_relation.name
  RETURN tf.gene_symbol, tf.fbgn, target_gene.gene_symbol,
         target_gene.fbgn, region2gene_relation.gene_rank, motif.motif_name,
         tf2motif_relation.motif_rank, tf2motif_relation.NES_score, target_region.region_id,
         target_region.chromosome, target_region.start_position, target_region.end_position,
         motif2region_relation.region_rank, type(tf2motif_relation), tf2motif_relation.confidence_level,
         tf2motif_relation.coexpression_method_type, tf2motif_relation.coexpression_method_threshold

Responsive image

CyNeo4j requests via cytoscape cypher queries

Install Cytoscape and add the cyNeo4j plugin as explained here
Start Cytoscape and go to "Apps/cyNeo4j/Connect to Instance" and enter the following URL: http://neo4j-eyenetwork.aertslab.org
To request the database, go to "Apps/cyNeo4J/Cypher Query" enter your query in the input box and press OK. Queries are the same than in the "Custom requests via the Cypher form" section excepted that properties should not be returned (all nodes and edges properties properties will anyway be displayed in the Cytoscape Table Panel).
The requested part of the network is then downloaded from the database and will appear in the Cytoscape control panel. Right click on it and "Create view" to see the network appearing in the main panel.

Gene to co-expressed TFs

e.g. Search with which TFs glass is found to be co-expressed with (no other information will be given than the TF names)

MATCH (coexpressedgene:`CoExpressedGenes` { gene_symbol: "gl" })-[coexpressed_relation:`gene_coexpressed_with_TFs`]->(tf:`TFs`)
  RETURN
         coexpressedgene, coexpressed_relation, tf

Responsive image

TF to coexpressed genes

e.g. Search for genes co-expressed with glass TF (no other information will be given than the gene names)

MATCH (tf:`TFs` { gene_symbol: "gl" })-[coexpressed_relation:`TF_coexpressed_with_genes`]->(coexpressedgene:`CoExpressedGenes`)
  RETURN
         tf, coexpressed_relation, coexpressedgene

Responsive image

Target gene to TFs

e.g. Search for predicted TF and DNA region regulating glass expression (dataset from PTM greater 10e-8)

MATCH (tf:`TFs`)-[tf2motif_relation:`PTM_greater_10e-8_high_confidence_predicted_target_for_TF`]
->(motif:`Motifs`)-[motif2region_relation:`PTM_greater_10e-8_high_confidence_predicted_target_for_TF`]
->(target_region:`Regions`)-[region2gene_relation:`PTM_greater_10e-8_high_confidence_predicted_target_for_TF`]
->(target_gene:`HighConfidencePredictedTargetGenes` { gene_symbol: "gl" })
  WHERE tf2motif_relation.name = motif2region_relation.name
        AND tf2motif_relation.name = region2gene_relation.name
  RETURN
         tf, tf2motif_relation, motif,
         motif2region_relation, target_region,
         region2gene_relation, target_gene

Responsive image

For example here glass is predicted to be regulated by Lz and Gl via chr3R-reg15410 and by Gl via chr3R-reg15411 (the dm3 coordinates of this region are displayed in the Cytoscape table panel)

TF to target genes

e.g. Search for gl target genes predicted from PTM greater 10e-8 dataset

MATCH (tf:`TFs` { gene_symbol: "gl" })-[tf2motif_relation:`PTM_greater_10e-8_high_confidence_predicted_target_for_TF`]
->(motif:`Motifs`)-[motif2region_relation:`PTM_greater_10e-8_high_confidence_predicted_target_for_TF`]
->(target_region:`Regions`)-[region2gene_relation:`PTM_greater_10e-8_high_confidence_predicted_target_for_TF`]
->(target_gene:`HighConfidencePredictedTargetGenes`)
  WHERE tf2motif_relation.name = motif2region_relation.name
        AND tf2motif_relation.name = region2gene_relation.name
  RETURN
         tf, tf2motif_relation, motif,
         motif2region_relation, target_region,
         region2gene_relation, target_gene

Responsive image

TF to motifs

e.g. Search for binding motifs related to glass in our collection.

MATCH (tf:`TFs` { gene_symbol: "gl" })-[tf_to_motif:`is_possible_TF_for_motif`]->(motif:`Motifs`)
  RETURN
         tf, tf_to_motif, motif

Responsive image